Pro Tip: Scatterplots with two metric variables/timeseries

marina_pollehn — Wed, 26 Nov 2025 14:46:29 GMT

I am trying to break down how you can use the new scatterplot visualization (especially as using it with two metric timerseries does not seem to be a default option). So, I wrote a small blog post on a workaround.

You can find my original post here: Mini Dynatrace Newsletter - November 2025 Edition – Conclusion Xforce Tech Playground

The scatterplot feature exists since 21 oct 2025, SaaS version 1.326 (auto-update, so if you have SaaS this feature is available automatically)

Summary (from the release notes): “You can now use scatterplots in Dashboards and Notebooks to visualize data relationships and identify patterns, such as correlations between response time and request count. This new visualization helps you analyze metrics more effectively and uncover insights in your observability data.”

Mini Demo: Let us start off easy with a scatterplot of one metric (y-axis) against the timeframe (x-axis), so a metric over time. This is a nice alternative to line graphs.

timeseries avg(dt.service.request.response_time), by:{dt.entity.service}
|fieldsAdd entityName(dt.entity.service)
|filter dt.entity.service.name == "CreditCardValidation"

For my queries, I used the Dynatrace demo environment.

If I select a bigger timeframe now, Dynatrace will adjust the interval, meaning that many datapoints will be merged to one. I am not keen on that, as it defeats the purpose of a scatterplot which is supposed to show all datapoints, but we can avoid it by adding an interval ourselves Like that:

timeseries avg(dt.service.request.response_time), interval:1m, by:{dt.entity.service}
|fieldsAdd entityName(dt.entity.service)
|filter dt.entity.service.name == "CreditCardValidation"

Now let’s get started on the interesting part, with two different “metric variables” on the x-axis and the y-axis. A small warning/disclaimer: If you create two metrics as a line chart on a dashboard, you can actually also just append them - less beautiful maybe, but it works. As we do want to know the exact y-value for every x-value, to understand their relationship (and these values will be shown without their timestamp on the dashboard), this approach will not work (at least not without additional data engineering with DQL). So you have to use join or lookup commands or create two timeseries immediately in the first step (see my example). More information on joins and lookups: Dynatrace Docs - DQL Correlation and join commands

First, we create two metric timeseries:

timeseries {response_time_p99 = percentile(dt.service.request.response_time, 99),
request_count = sum(dt.service.request.count)},
interval: 1m, by:{dt.entity.service}, union:true
|fieldsAdd entityName(dt.entity.service)
|filter dt.entity.service == "SERVICE-1234567891011"
//enter your own service ID here

Unfortunately, we cannot choose the scatterplot visualization immediately. I actually would have liked that… so we will go for a workaround to make it possible. This is not documented in the release notes or in the Dynatrace Documentation so feel free to follow my steps.

We need to look at a record list, and no longer at two timeseries. The following commands will convert the timeseries to single records:

// Expanding timeseries to single records
|fields all = iCollectArray(record(response_time_p99= response_time_p99[],
request_count = request_count[])),dt.entity.service.name
|expand all
|fieldsAdd request_count = all[request_count], response_time_p99 = all[response_time_p99]
|fieldsRemove all

Result:

Now it makes sense to remove the outliers (a boxplot would be great now to know which ones to exclude, but that feature does not exist in Dynatrace yet). So, we add the following rules (based on the visual impression of outliers):

//Removing outliers
|filterOut request_count > 150 //(number of requests)
|filterOut response_time_p99 > 100000 //(100ms)

Result:

The amount of requests per minute seems to have a positive relationship with the response time of the slowest 1% requests (more requests are related to a higher response time).

Let’s check if the visual impression of a positive correlation between the “slowest 1% requests” response time and the request count actually exists. For that, we will add the |summarize correlation() command.

//Pearson correlation coefficient
|summarize correlation(request_count,response_time_p99)

The result is indeed a positive relationship:

|summarize correlation() already exists for some time, but does fit the use case here, that’s why I included it.

My 2cts: Mostly happy about the feature. More dashboarding options and more data science is always a good step forward. I do miss the option to add a trendline (see the example with R).

For me, this belongs to a good scatterplot. Unfortunately, there is also no documentation page for scatterplots so far, so the link from the DQL tile does not work yet:

Furthermore, it is not possible yet to simply add two timeseries and turn them into a scatterplot with a normal metrics tile or DQL tile without intermediate steps (see the error message). That could be improved in the future to make this feature more accessible to everyone.

Re: Pro Tip: Scatterplots with two metric variables/timeseries

AntonPineiro — Wed, 19 Nov 2025 12:28:36 GMT

Thank you so much!

Re: Pro Tip: Scatterplots with two metric variables/timeseries

Mizső — Fri, 28 Nov 2025 17:01:05 GMT

Hi @marina_pollehn ,

Great TIP! Thank you very much!

Re: Pro Tip: Scatterplots with two metric variables/timeseries

AntonioSousa — Fri, 28 Nov 2025 19:55:19 GMT

@marina_pollehn ,

Thanks for the Pro Tip.

Also noticed that you saw the Holiday-aware hack that Dynatrace just did in time for Thanksgiving. It's really the second most voted Product Idea in the Community (I know because it's mine and have been tracking it for more than 7 years now), but unusable except for the US at the moment.

Re: Pro Tip: Scatterplots with two metric variables/timeseries

marina_pollehn — Mon, 01 Dec 2025 14:20:33 GMT

I just tested and apparently now, simply creating two timeseries is now allowed for a scatterplot, so this was a nice workaround, but it is not necessarily needed anymore. 🙂 Both ways work now.

So now you could simply create a DQL tile with

timeseries {response_time_p99 = percentile(dt.service.request.response_time, 99), request_count = sum(dt.service.request.count)}, interval: 1m, by:{dt.entity.service}, union:true |fieldsAdd entityName(dt.entity.service) |filter dt.entity.service == "SERVICE-1234567891011"

and switch to a scatterplot visualization immediately. Nice improvement to make it more user friendly.

topic Re: Pro Tip: Scatterplots with two metric variables/timeseries in Dynatrace tips

Pro Tip: Scatterplots with two metric variables/timeseries

Re: Pro Tip: Scatterplots with two metric variables/timeseries

Re: Pro Tip: Scatterplots with two metric variables/timeseries

Re: Pro Tip: Scatterplots with two metric variables/timeseries

Re: Pro Tip: Scatterplots with two metric variables/timeseries