# Getting error in DQL in fetching MQ information on filtering by QM names

**URL:** <https://community.dynatrace.com/t/getting-error-in-dql-in-fetching-mq-information-on-filtering-by-qm-names/54555>\
**Category:** DQL\
**Tags:** dql, dynatrace-managed\
**Created:** [January 7, 2026, 5:16pm UTC](https://community.dynatrace.com/t/getting-error-in-dql-in-fetching-mq-information-on-filtering-by-qm-names/54555 "2026-01-07T17:16:52Z")\
**Posts on this page:** 2\
**Page:** 1

<div class="post-metadata">

**Author:** ![pds\_sis](https://avatars.discourse-cdn.com/v4/letter/p/3ec8ea/32.png) [@pds\_sis](https://community.dynatrace.com/u/pds_sis)\
**Post date:** [January 7, 2026, 5:16pm UTC](https://community.dynatrace.com/t/getting-error-in-dql-in-fetching-mq-information-on-filtering-by-qm-names/54555/1 "2026-01-07T17:16:52Z")

</div>

Hi Team

I am trying to filterout specific MQ’s however getting error “filter name”. Can anyone guide me on that please.

This is the query :

timeseries { availability = avg(ibmmq.queue\_manager.availability), dlq\_depth = avg(ibmmq.queue\_manager.dlq\_depth), active\_channels = avg(ibmmq.queue\_manager.active\_channels), connections = avg(ibmmq.queue\_manager.connections), uptime = avg(ibmmq.queue\_manager.uptime) }, by: { `dt.entity.ibmmq:queue_manager` }  
| fieldsAdd name = entityName(`dt.entity.ibmmq:queue_manager`)  
| fieldsAdd availability = arrayLast(availability)  
| sort availability asc  
| fieldsAdd dlq\_depth = arrayLast(dlq\_depth)  
| fieldsAdd active\_channels = arrayLast(active\_channels)  
| fieldsAdd connections = arrayLast(connections)  
| fieldsAdd uptime = arrayLast(uptime)  
| filterOut isNull(name)  
| filter name in(“entity.queue\_manager”, {“SCP1”, “SCP2”, “SISP”})  
| fields `Name` = name, `Availability` = availability, `DLQ Depth` = dlq\_depth, `Active channels` = active\_channels, `Connections` = connections, `Uptime` = uptime  
| limit 10

---

<div class="post-metadata">

**Author:** ![t\_pawlak](https://dub1.discourse-cdn.com/dynatrace/user_avatar/community.dynatrace.com/t_pawlak/32/14991_2.png) [@t\_pawlak](https://community.dynatrace.com/u/t_pawlak)\
**Post date:** [January 8, 2026, 12:01pm UTC](https://community.dynatrace.com/t/getting-error-in-dql-in-fetching-mq-information-on-filtering-by-qm-names/54555/2 "2026-01-08T12:01:07Z")

</div>

Hi,

The error was caused by incorrect usage of in() in DQL.  
name is already a string returned by entityName(), so it can’t be filtered using in(“entity.queue\_manager”, …) or in() with parentheses.

In my case, entityName() contains additional text, so using startsWith() works correctly.  
I tested this, and it not recive errors:

```markup
timeseries {
  availability = avg(ibmmq.queue_manager.availability),
  dlq_depth = avg(ibmmq.queue_manager.dlq_depth),
  active_channels = avg(ibmmq.queue_manager.active_channels),
  connections = avg(ibmmq.queue_manager.connections),
  uptime = avg(ibmmq.queue_manager.uptime)
}, by: { `dt.entity.ibmmq:queue_manager` }
| fieldsAdd name = entityName(`dt.entity.ibmmq:queue_manager`)
| fieldsAdd availability = arrayLast(availability)
| fieldsAdd dlq_depth = arrayLast(dlq_depth)
| fieldsAdd active_channels = arrayLast(active_channels)
| fieldsAdd connections = arrayLast(connections)
| fieldsAdd uptime = arrayLast(uptime)
| filterOut isNull(name)
| filter startsWith(name, "SCP1") or startsWith(name, "SCP2") or startsWith(name, "SISP")
| sort availability asc
| fields
    `Name` = name,
    `Availability` = availability,
    `DLQ Depth` = dlq_depth,
    `Active channels` = active_channels,
    `Connections` = connections,
    `Uptime` = uptime
| limit 10

```
